MySQL Windows 服務註冊/啟動/停用/卸載批次腳本

MySQL Windows 服務註冊/啟動/停用/卸載批次腳本

安裝啟動腳本：my_install.bat

@echo off
set MYSQL_DIR=%~dp0
if not "%MYSQL_HOME%"=="" (
  if not "%MYSQL_HOME%"=="%MYSQL_DIR%" (
    echo MYSQL_HOME=%MYSQL_HOME% != MYSQL_DIR=%MYSQL_DIR%
    goto my_ends
  )
) else (
  set MYSQL_HOME=%MYSQL_DIR%
  echo MYSQL_HOME must be set as MYSQL_DIR=%MYSQL_DIR%
)
set PATH=%MYSQL_HOME%bin;%MYSQL_HOME%lib;%PATH%

mysqladmin -uroot ping 1>nul 2>nul
if "%ERRORLEVEL%"=="0" (
  echo Mysql is running.
  goto my_ends
)

echo "MYSQL_HOME = %MYSQL_HOME%"
echo Install and start mysql server ...
mysqld --install mysql_srv
sc config mysql_srv start= DEMAND
net start mysql_srv

mysqladmin -uroot ping 1>nul 2>nul
if "%ERRORLEVEL%"=="0" echo "Mysql started successfully"

:my_ends
cmd /K

停用卸載腳本：my_uninstall.bat

@echo off
set MYSQL_DIR=%~dp0
if not "%MYSQL_HOME%"=="" (
  if not "%MYSQL_HOME%"=="%MYSQL_DIR%" (
    echo MYSQL_HOME=%MYSQL_HOME% != MYSQL_DIR=%MYSQL_DIR%
    goto my_ends
  )
) else (
  set MYSQL_HOME=%MYSQL_DIR%
)
set PATH=%MYSQL_HOME%\bin;%MYSQL_HOME%\lib;%PATH%

echo "MYSQL_HOME = %MYSQL_HOME%"
echo Stop and uninstall mysql server ...
mysqladmin -uroot ping 1>nul 2>nul
if "%ERRORLEVEL%"=="0" (
  net stop mysql_srv
)
mysqld --remove mysql_srv

:my_ends
pause

使用說明

• 將腳本置於 MySQL 解壓根目錄（含 bin、lib）
• 雙擊執行，自動設定 MYSQL_HOME、PATH、註冊服務名 mysql_srv
• sc config start= DEMAND 設為手動啟動，避免開機資源佔用
• 卸載前自動偵測服務運行狀態並停止